918af4f3ac
* change simulator svg * change radio image * Remove google fonts cdn * change color of 'advanced' button * font fix * font fix 2 * display fix * change fullsceen simulator bg * Continuous servo * handle continuous state * adding shims * update rendering for continuous servos * fixing sim * fix sig * typo * fix sim * bump pxt * bump pxt * rerun travis * Input blocks revision - add Button and Pin event types - merge onPinPressed & onPinReleased in new onPinEvent function - create new onButtonEvent function * update input blocks in docs and tests * remove device_pin_release block * Hide DAL.x behind Enum * bring back deprecated blocks, but hide them * shims and locales files * fix input.input. typing * remove buildpr * bump V3 * update simulator aspect ratio * add Loudness Block * revoke loudness block * Adds soundLevel To be replaced by pxt-common-packages when DAL is updated. * Remove P0 & P3 from AnalogPin Co-authored-by: Juri <gitkraken@juriwolf.de>
49 lines
1.3 KiB
ArmAsm
49 lines
1.3 KiB
ArmAsm
.syntax unified
|
|
.section .text.neopixel_send_buffer_core
|
|
.global neopixel_send_buffer_core
|
|
|
|
neopixel_send_buffer_core:
|
|
push {r4,r5,r6,r7,lr}
|
|
|
|
mov r4, r1 // ptr
|
|
mov r5, r2 // len
|
|
|
|
ldr r0, [r0, #8] // get mbed DigitalOut from MicroBitPin
|
|
ldr r1, [r0, #4] // r1-mask for this pin
|
|
ldr r2, [r0, #16] // r2-clraddr
|
|
ldr r3, [r0, #12] // r3-setaddr
|
|
|
|
b .start
|
|
|
|
.nextbit: // C0
|
|
str r1, [r3, #0] // pin := hi C2
|
|
tst r6, r0 // C3
|
|
bne .islate // C4
|
|
str r1, [r2, #0] // pin := lo C6
|
|
.islate:
|
|
lsrs r6, r6, #1 // r6 >>= 1 C7
|
|
bne .justbit // C8
|
|
|
|
// not just a bit - need new byte
|
|
adds r4, #1 // r4++ C9
|
|
subs r5, #1 // r5-- C10
|
|
bcc .stop // if (r5<0) goto .stop C11
|
|
.start:
|
|
movs r6, #0x80 // reset mask C12
|
|
nop // C13
|
|
|
|
.common: // C13
|
|
str r1, [r2, #0] // pin := lo C15
|
|
// always re-load byte - it just fits with the cycles better this way
|
|
ldrb r0, [r4, #0] // r0 := *r4 C17
|
|
b .nextbit // C20
|
|
|
|
.justbit: // C10
|
|
// no nops, branch taken is already 3 cycles
|
|
b .common // C13
|
|
|
|
.stop:
|
|
str r1, [r2, #0] // pin := lo
|
|
|
|
pop {r4,r5,r6,r7,pc}
|